restart:with(Maplets): with(Maplets[Tools]): with(Maplets[Elements]): with(plots):
StartEngine();lightorange:="#FFB300":Ms:=[-1,0,1,2,3,4,5]:
randM:=rand(1..7):
As:=[1,2,3,4,5]:
randA:=rand(1..5):
Ps:=[1, 2, 3, 4, 5, 6, 7, 8]:
randP:=rand(1..8):
Phis:=[0, Pi, Pi/2, 3*Pi/2, Pi/4, 3*Pi/4, 5*Pi/4, 7*Pi/4, Pi/6, Pi/3, 2*Pi/3, 5*Pi/6, 7*Pi/6, 4*Pi/3, 5*Pi/3, 11*Pi/6]:
randPhi:=rand(1..16):
funcdisplay:=A*sin(2*Pi*x/P-phi)+M:graph:=proc()
global Ms,As,Ps,Phis,randM,randA,randP,randPhi,M1,A1,P1,Phi1,func,p1,p3;
M1:=Ms[randM()];
A1:=As[randA()];
P1:=Ps[randP()];
Phi1:=Phis[randPhi()];
func:=A1*sin(2*Pi*x/P1-Phi1)+M1;
p1:=plot(func,x=-6..6,min(M1-A1,0)-1..max(M1+A1,0)+1, color=blue, xtickmarks=13, ytickmarks=[M1-A1, M1, M1+A1]):
p3:=plot(func,x=-6..6,min(M1-A1,0)-1..max(M1+A1,0)+1, color=green, xtickmarks=13, ytickmarks=[M1-A1, M1, M1+A1]):
Set('PL1' = p1):
Set('TFA' = "");
Set('TFM' = "");
Set('TFP' = "");
Set('TFPhi' = "");
Set('reply' = "", 'reply'(background)=white,'reply'(foreground)=black);
end proc:hintM:=proc()
Set('reply' = cat("The mean value is the height of the centerline of the sine curve."),
'reply'(background)=lightorange,'reply'(foreground)=black);
end proc:
hintA:=proc()
Set('reply' = cat("The amplitude is the vertical distance from the centerline to the top or bottom of the sine curve."),
'reply'(background)=lightorange,'reply'(foreground)=black);
end proc:
hintP:=proc()
Set('reply' = cat("The period is the horizontal distance between successive maxima of the sin curve."),
'reply'(background)=lightorange,'reply'(foreground)=black);
end proc:
hintPhi:=proc()
Set('reply' = cat("The phase shift is the amount of a cycle the sine function is shifted to the right. It is expressed in radians as a multiple of Pi."),
'reply'(background)=lightorange,'reply'(foreground)=black);
end proc:check_answer:=proc()
global p1,p3,M1,A1,P1,Phi1;
local user_M,user_A,user_P,user_Phi,user_func,p2;
user_M:=Get('TFM'::'realcons'):
user_A:=Get('TFA'::'realcons'):
user_P:=Get('TFP'::'realcons'):
user_Phi:=Get('TFPhi'::'realcons'):
user_func:=user_A*sin(2*Pi*x/user_P-user_Phi)+user_M;
p2:=plot(user_func,x=-2*Pi..2*Pi,min(M1-A1,0)-1..max(M1+A1,0)+1, color=red, ytickmarks=[M1-A1, M1, M1+A1]):
if user_M = M1 then
if user_A = A1 then
if user_P = P1 then
if user_Phi = Phi1 then
Set('reply' = "RIGHT!",
'reply'(background)=green,'reply'(foreground)=black);
Set('PL1' = p3);
return;
else
Set('reply' = "You input the wrong value of Phi.\nThe plot shows the original function in blue and your function in red.\nRead the hints, correct your answers, and check it again.",
'reply'(background)=red,'reply'(foreground)=white);
end if;
else
Set('reply' = "You input the wrong value of P, and possibly others.\nThe plot shows the original function in blue and your function in red.\nRead the hints, correct your answers, and check it again.",
'reply'(background)=red,'reply'(foreground)=white);
end if;
else
Set('reply' = "You input the wrong value of A, and possibly others.\nThe plot shows the original function in blue and your function in red.\nRead the hints, correct your answers, and check it again.",
'reply'(background)=red,'reply'(foreground)=white);
end if;
else
Set('reply' = "You input the wrong value of M, and possibly others.\nThe plot shows the original function in blue and your function in red.\nRead the hints, correct your answers, and check it again.",
'reply'(background)=red,'reply'(foreground)=white);
end if;
Set('PL1' = display(p1,p2));
end proc:show_answer:=proc()
global p3,M1,A1,P1,Phi1;
Set('TFM' = M1);
Set('TFA' = A1);
Set('TFP' = P1);
Set('TFPhi' = Phi1);
Set('PL1' = p3):
Set('reply' = cat("Next time try it yourself!"),
'reply'(background)=lightorange,'reply'(foreground)=black);
end proc:sine_curve:= Maplet(onstartup = RunWindow(MAIN), Font[helv10]("helvetica",10),
Window[MAIN]('title'="Properties of Sine Curves",
[ halign=none,
[ Button("New Function", onclick=Evaluate('function' = "graph")),
HorizontalGlue(),
Button("Quit", Shutdown())
],
[ [ [ "The graph of a function of the form",
HorizontalGlue()
],
[ MathMLViewer(value=MathML[Export]( funcdisplay ), width=200, height=60)
],
[ "is shown at the right . . .",
HorizontalGlue()
],
[ "Identify each of the following:",
HorizontalGlue()
]
],
Plotter['PL1']('width'=300, 'height'=200)
],
[ "Mean Value: ",
HorizontalGlue(),
"M =",
TextField['TFM']('width'=25,background=white,foreground=black),
HorizontalGlue(),
Button("Hint",Evaluate('function'="hintM"))
],
[ "Amplitude: ",
HorizontalGlue(),
"A =",
TextField['TFA']('width'=25,background=white,foreground=black),
HorizontalGlue(),
Button("Hint",Evaluate('function'="hintA"))
],
[ "Period: ",
HorizontalGlue(),
"P =",
TextField['TFP']('width'=25,background=white,foreground=black),
HorizontalGlue(),
Button("Hint",Evaluate('function'="hintP"))
],
[ "Phase Shift:",
HorizontalGlue(),
"Phi =",
TextField['TFPhi']('width'=25,background=white,foreground=black),
HorizontalGlue(),
Button("Hint",Evaluate('function'="hintPhi"))
],
[ HorizontalGlue(),
Button("Check Answers",Evaluate('function'="check_answer")),
HorizontalGlue(),
Button("Show Answers",Evaluate('function'="show_answer")),
HorizontalGlue()
],
[ TextBox['reply']('width'=70, 'height'=4, 'editable'='false', background=white)
],
BoxRow('background'="#DDFFFF", 'inset'=0, 'spacing'=0,
Label("Programmers: Shea Sanford / Jared Tschirgi", 'font'=helv10),
HorizontalGlue(),
Label("Copyright 2006, D.B. Meade and P.B. Yasskin", 'font'=helv10),
HorizontalGlue(),
Label("v. 1.2a May 2006", 'font'=helv10)
)
]
)
):Maplets[Display](sine_curve);