Center of Mass of a Plate
Sarah Mannen and Talha Ramzan
restart;
with(Maplets[Tools]): with(Maplets[Elements]): with(plots): with(RandomTools):
StartEngine();
randomize():
lightorange:="#FFB300":
randx1:=rand(0..2):
randx2:=rand(4..6):
ask:=proc()
global f, g, x1, x2, pad, M, Mval, My, Myval, Mx, Mxval, X, Y, p1, p2, p3, p4;
local fmin, gmax, dy;
f:=sort(Generate(polynom(integer(range=-3..3), x, degree=2)));
g:=sort(Generate(polynom(integer(range=-3..3), x, degree=2)));
x1:=randx1();
x2:=randx2();
fmin:=minimize(f, x=x1..x2);
gmax:=maximize(g, x=x1..x2);
dy:=fmin-gmax;
if dy<0 then
f:=f-dy;
end if;
M:=Int(f-g,x=x1..x2);
Mval:=value(M);
My:=Int(x*(f-g),x=x1..x2);
Myval:=value(My);
Mx:=1/2*Int(f^2-g^2,x=x1..x2);
Mxval:=value(Mx);
X:=value(My/M);
Y:=value(Mx/M);
Set(question=cat("Find the centroid of the region between f(x)=",
convert(f,string),", g(x)=",convert(g,string),", x=",
x1,", and x=",convert(x2,string),"."));
Set(TFM="");
Set(TFMval="");
Set(TFMy="");
Set(TFMyval="");
Set(TFMx="");
Set(TFMxval="");
Set(TFX="");
Set(TFY="");
Set(reply="");
pad:=(x2-x1)/5;
p1:=plot([f,g], x=x1..x2, color=[red,blue], thickness=2);
p2:=plot([[[x1,eval(f,x=x1)],[x1,eval(g,x=x1)]],
[[x2,eval(f,x=x2)],[x2,eval(g,x=x2)]]], color=black, thickness=2);
p3:=plot(0, x=x1..x2, color=white);
p4:=plot(0, x=x1..x2, color=white);
Set(graph=display([p1,p2], view=[x1-pad..x2+pad,default]));
end proc:
hintM:=proc()
Set(TFM=" Int( f(x) - g(x), x=a..b)"):
end proc:
checkM:=proc()
global M, Mval;
local userM, userMval;
userM:=Get(TFM::{function, realcons &* function}):
userMval:=Get(TFMval::realcons):
if simplify(userM-M)=0 and userMval=Mval then
Set(reply="Correct!")
elif userM=M then
Set(reply="The integral is correct, but the value is wrong. Try again.")
else
Set(reply="The integral is wrong. Try again.")
end if;
end proc:
showM:=proc()
global M, Mval:
Set(TFM=M):
Set(TFMval=Mval):
end proc:
hintMy:=proc ()
Set(TFMy=" Int( x * ( f(x) - g(x) ), x=a..b)")
end proc:
checkMy:=proc()
global My, Myval:
local userMy, userMyval:
userMy:=Get(TFMy::{function, realcons &* function}):
userMyval:=Get(TFMyval::realcons):
if simplify(userMy-My)=0 and userMyval=Myval then
Set(reply="Correct!"):
elif userMy=My then
Set(reply="The integral is correct, but the value is wrong. Try again."):
else
Set(reply="The integral is wrong. Try again."):
end if:
end proc:
showMy:=proc ()
global My, Myval:
Set(TFMy=My);
Set(TFMyval=value(My))
end proc:
hintMx:=proc ()
Set(TFMx=" 1/2 * Int( f(x)^2 - g(x)^2, x=a..b)")
end proc:
checkMx:=proc ()
global Mx, Mxval;
local userMx, userMxval;
userMx:=Get(TFMx::{function, realcons &* function});
userMxval:=Get(TFMxval::realcons);
if simplify(userMx-Mx)=0 and userMxval=Mxval then
Set(reply="Correct! ")
elif userMx=Mx then
Set(reply="The integral is correct, but the value is wrong. Try again.")
else
Set(reply="The integral is wrong. Try again.")
end if
end proc:
showMx:=proc ()
global Mx, Mxval;
Set(TFMx=Mx);
Set(TFMxval=value(Mx))
end proc:
hintX:=proc ()
Set(TFX=" My / M")
end proc:
checkX:=proc ()
global X, f, g, x1, x2, pad, p1, p2, p3, p4;
local userX;
userX:=Get(TFX::realcons);
if userX=X then
Set(reply="Correct!");
p3:=plot([[X,eval(f, x=X)], [X,eval(g, x=X)]], color=green);
else
Set(reply="Incorrect. Try again.");
p3:=plot([[userX,eval(f, x=userX)], [userX,eval(g, x=userX)]], color=red);
end if;
Set(graph=display([p1,p2, p3, p4], view=[x1-pad..x2+pad,default]));
end proc:
showX:=proc ()
global X, f, g, x1, x2, pad, p1, p2, p3, p4;
Set(TFX=X);
p3:=plot([[X,eval(f, x=X)], [X,eval(g, x=X)]], color=green);
Set(graph=display([p1,p2, p3, p4], view=[x1-pad..x2+pad,default]));
end proc:
hintY:=proc ()
Set(TFY=" Mx / M")
end proc:
checkY:=proc ()
global Y, x1, x2, pad, p1, p2, p3, p4;
local userY;
userY:=Get(TFY::realcons);
if userY=Y then
Set(reply="Correct!");
p4:=plot(Y, x=x1..x2, color=green);
else
Set(reply="Incorrect. Try again.");
p4:=plot(userY, x=x1..x2, color=red);
end if;
Set(graph=display([p1,p2, p3, p4], view=[x1-pad..x2+pad,default]));
end proc:
showY:=proc ()
global Y, x1, x2, pad, p1, p2, p3, p4;
Set(TFY=Y);
p4:=plot(Y, x=x1..x2, color=green);
Set(graph=display([p1,p2, p3, p4], view=[x1-pad..x2+pad,default]));
end proc:
CenterOfMass:=Maplet(onstartup=RunWindow(MAIN),
Window[MAIN](title="Center of Mass of a Plate with Constant Density",
defaultbutton=BMT,
[ halign=none, valign=none, inset=0, spacing=0,
[ halign=none,
Button("New Problem", Evaluate(function="ask"), background=magenta),
HorizontalGlue(),
Button("Quit", Shutdown(), background=pink)
],
[ halign=none, valign=none, inset=0,
[ halign=none, valign=none, inset=0,
[ halign=none, border=true,
caption="Problem Statement",
TextBox[question](width=30, height=4, editable=false)
],
VerticalGlue(),
BoxColumn( inset=0, border=true,
caption="Find the total mass. Enter the integral and value.",
[ halign=none,
"M =",
TextField[TFM](width=20, background=turquoise),
"=",
TextField[TFMval](width=10, background=turquoise),
HorizontalGlue()
],
[ halign=none,
HorizontalGlue(),
Button[BMT]("Template", Evaluate(function="hintM"), background=lightorange),
Button("Check", Evaluate(function="checkM"), background=green),
Button("Show", Evaluate(function="showM"), background=lightorange),
HorizontalGlue()
]
)
],
[ halign=none, valign=none, border=true,
caption="Plot of Plate",
Plotter[graph](plot(0,x=0..6), width=300, height=200)
]
],
[ halign=none, valign=none, inset=0,
[ halign=none, valign=none, inset=0, spacing=0, border=true,
BoxColumn( valign=none, inset=0, border=true,
caption="Find the moment about the y-axis (integral and value):",
[ halign=none,
"My =",
TextField[TFMy](width=20, background=turquoise),
"=",
TextField[TFMyval](width=10, background=turquoise)
],
[ halign=none,
HorizontalGlue(),
Button("Template", Evaluate(function="hintMy"), background=lightorange),
Button("Check", Evaluate(function="checkMy"), background=green),
Button("Show", Evaluate(function="showMy"), background=lightorange),
HorizontalGlue()
]
),
BoxColumn( valign=none, inset=0, spacing=0, border=true,
caption="Find the x-coordinate of the center of mass:",
[ halign=none,
HorizontalGlue(),
"X =",
TextField[TFX](width=10, background=turquoise),
HorizontalGlue()
],
[ halign=none,
HorizontalGlue(),
Button("Template", Evaluate(function="hintX"), background=lightorange),
Button("Check", Evaluate(function="checkX"), background=green),
Button("Show", Evaluate(function="showX"), background=lightorange),
HorizontalGlue()
]
)
],
[ halign=none, valign=none, inset=0, spacing=0, border=true,
BoxColumn( valign=none, inset=0, border=true,
caption="Find the moment about the x-axis (integral and value):",
[ halign=none,
"Mx =",
TextField[TFMx](width=20, background=turquoise),
"=",
TextField[TFMxval](width=10, background=turquoise)
],
[ halign=none,
HorizontalGlue(),
Button("Template", Evaluate(function="hintMx"), background=lightorange),
Button("Check", Evaluate(function="checkMx"), background=green),
Button("Show", Evaluate(function="showMx"), background=lightorange),
HorizontalGlue()
]
),
BoxColumn( valign=none, inset=0, spacing=0, border=true,
caption="Find the y-coordinate of the center of mass:",
[ halign=none,
HorizontalGlue(),
"Y =",
TextField[TFY](width=10, background=turquoise),
HorizontalGlue()
],
[ halign=none,
HorizontalGlue(),
Button("Template", Evaluate(function="hintY"), background=lightorange),
Button("Check", Evaluate(function="checkY"), background=green),
Button("Show", Evaluate(function="showY"), background=lightorange),
HorizontalGlue()
]
)
]
],
TextField[reply](width=60),
[ "Programmers: Sarah Mannen and Talha Ramzan",
HorizontalGlue(),
"\302\251 copyright P. Yasskin 2007"
]
]
)
):
Maplets[Display](CenterOfMass);