David MiglUsing Maclaurin Series to Integraterestart:with(Maplets[Tools]): with(Maplets[Elements]):
StartEngine();randomize():colorbkgd:=wheat:
colordisable:=colorbkgd:
lightcyan:="#DDFFFF":
lightorange:="#FFB300":ColorNewButton:=magenta:
ColorPrevButton:=turquoise:
ColorInput:=turquoise: ColorInputFrgd:=black:
ColorCheckButton:=green:
ColorShowButton:=lightorange:
ColorShow:=lightorange: ColorShowFrgd:=black:
ColorReturnButton:=magenta:
ColorFooter:=lightcyan:
ColorReplyDefault:=white: ColorReplyFrgdDefault:=black:
ColorFormulasButton:=lightorange:
ColorHintButton:=lightorange:
ColorCloseButton:=pink: # or Quit, Clear, Reset, Cancel
ColorCorrect:=green: ColorCorrectFrgd:=black:
ColorIncorrect:=red: ColorIncorrectFrgd:=white:
ColorWarning:=yellow: ColorWarningFrgd:=black:FontFooter:=Font("helvetica",10):CaptionGoal:=
"Goal: Use a Maclaurin Series to evaluate or estimate the integral:":
CaptionStep1:=
"Step 1: Find a Maclaurin series for the integrand. Start from a known series. Make substitutions. Differentiate. Integrate. Or Multiply by powers of x.":
CaptionStep2:=
"Step 2: Find a Maclaurin series for the integral. Integrate the terms of the above series.":
CaptionStep3:=
"Step 3: Use the first THREE terms of the series to approximate the definite integral.":TEXTBUpdate:=
"Update":
TEXTBClose:=
"Close":
TEXTtitlePREVIEW:=
"Preview":
TEXTBFormulaUse:=
"Use":
TEXTreplyPreview:=
"You must enter an expression to be previewed.":
TEXT1L1:=
" = ":
TEXTS3Disabled:=
"\134n\134nYou may skip this step since you are not computing a definite integral.\134n\134n\134n":
TEXTS3Note:=
"The programmer deems that estimating the error in approximating this integral is beyond the scope of this maplet. Including this functionality into this maplet would excessively complicate it. Enough material remains to write another maplet on using the Alternating Series Estimation Test and Taylor's Remainder Theorem to estimate the error in approximating definite integrals using series.":
TEXTReplyRequestValue:=
"Please enter a valid algebraic expression":
TEXTFeedbackShown:=
"Shown":
TEXTReplyStep1Correct:=
"Step 1 is correct":
TEXTReplyStep1Incorrect:=
"Step 1 is incorrect.":
TEXTHintStep3:=
"Write out the first three terms of the series. Next, evaluate them at the specified limits. The second evaluation (at x=0) usually comes out being 0.":Formula[1]:=Sum(t^n,n=0..infinity):
Formula[2]:=Sum((-1)^n*t^(n+1)/(n+1),n=0..infinity):
Formula[3]:=Sum(t^n/n!,n=0..infinity):
Formula[4]:=Sum((-1)^n*t^(2*n+1)/(2*n+1)!,n=0..infinity):
Formula[5]:=Sum((-1)^n*t^(2*n)/(2*n)!,n=0..infinity):
Formula[6]:=Sum((-1)^n*t^(2*n+1)/(2*n+1),n=0..infinity):terms:=[x^f*exp(c*x^d),
x^f*sin(c*x^d),
x^f*cos(c*x^d),
x^f*arctan(c*x^d),
x^f/(1+c*x^d),
x^f*ln(1+c*x^d)]:
randterm:=rand(1..nops(terms)):randc:=rand(1..11):
randd:=rand(2..4):
randb:=.1*rand(1..10):fvals:=[-2,-1,0,0,0,1,1,2,3,4]:
randf:=rand(1..nops(fvals)):New_Problem:=proc(argument)
global c, d, f,b,dori,luckyone,IntIndef,IntDef,whichterm,IndefSetting:
ClearEverything():
c:=randc();d:=randd();b:=randb();whichterm:=randterm();
f:=fvals[randf()];
luckyone:=terms[whichterm]:
while not type(limit(luckyone,x=0),finite)
or abs(abs(f)-abs(d))=1 #to make sure we don't end up with an easy u-substitution
do #to make sure we don't end up with an indefinite integral
f:=fvals[randf()];
luckyone:=terms[whichterm];
end do;
Set(MMLf(value)=MathML[Export](luckyone)):
IntIndef:=Int(luckyone, x):
IntDef:=Int(luckyone, x=0..b):
IndefSetting:=argument;
if IndefSetting=true
then Set(mainproblem(value) = MathML[Export](" I" = IntIndef));
# Evalute(function=
InvisibleStep3():
#):
Set(MMLVStep3(visible)=false):
else Set(mainproblem(value) = MathML[Export](" I" = IntDef));
end if;
EnableStep1():
end proc:InvisibleStep3:=proc()
Set(MMLVStep3(visible)=false):
Set(InputStep3(visible)=false):
Set(HintS3(visible)=false):
Set(CheckS3(visible)=false):
Set(ShowS3(visible)=false):
Set(S3equalsign(visible)=false):
Set(ReplyS3(visible)=false):
Set(S3Disabled(visible)=true):
Set(NoteS3(visible)=false):
end proc:ClearEverything:=proc()
Set(InputStep1(enabled)=false,InputStep1="",InputStep1(background)=white):
Set(PreviewS1(enabled)=false,PreviewS1(background)=colordisable):
Set(CheckS1(enabled)=false,CheckS1(background)=colordisable):
Set(ReplyS1="",ReplyS1(enabled)=false,ReplyS1(background)=colordisable,ReplyS1(foreground)=black):
Set(ShowS1(enabled)=false,ShowS1(background)=colordisable):
Set(PreviewS2(enabled)=false,PreviewS2(background)=colordisable):
Set(ShowS2(enabled)=false,ShowS2(background)=colordisable):
Set(InputStep2(enabled)=false,InputStep2="",InputStep2(background)=colordisable):
Set(PreviewS2(enabled)=false,PreviewS2(background)=colordisable):
Set(ReplyS2="",ReplyS2(enabled)=false,ReplyS2(background)=colordisable,ReplyS2(foreground)=black):
Set(ShowS2(enabled)=false,ShowS2(background)=colordisable):
Set(CheckS2(enabled)=false,CheckS2(background)=colordisable):
Set(MMLVStep2(value)=MathML[Export]("")):
Set(InputStep3(enabled)=false,InputStep3="",InputStep3(background)=colordisable):
Set(HintS3(enabled)=false,HintS3(background)=colordisable):
Set(CheckS3(enabled)=false,CheckS3(background)=colordisable):
Set(ReplyS3="",ReplyS3(enabled)=false,ReplyS3(background)=colordisable,ReplyS3(foreground)=black):
Set(ShowS3(enabled)=false,ShowS3(background)=colordisable):
Set(MMLVStep3(value)=MathML[Export]("")):
Set(reply="",reply(background)=ColorReplyDefault,reply(foreground)=ColorReplyFrgdDefault);
Set(S3Disabled(visible)=false):
Set(MMLVStep3(visible)=true):
Set(InputStep3(visible)=true):
Set(HintS3(visible)=true):
Set(CheckS3(visible)=true):
Set(ShowS3(visible)=true):
Set(S3equalsign(visible)=true):
Set(ReplyS3(visible)=true):
Set(NoteS3(visible)=true):
end proc:Preview:=proc(TFname)
local expr;
global CurrentTFname;
options `Copyright 2005, Philip B. Yasskin, Texas A&M Univ.`;
CurrentTFname := TFname;
if Get(TFname)="" then
Set(reply=TEXTreplyPreview,
reply(background)=ColorWarning, reply(foreground)=ColorWarningFrgd);
else
expr:=Get(TFname::anything, corrections=true, update=true);
Set(TFPreview = expr);
Set(MMLPreview(value) = MathML[Export](expr));
Set(ARunPreview(run)=true);
end if;
end proc:Update_Preview:=proc()
local expr;
global CurrentTFname;
options `Copyright 2005, Philip B. Yasskin, Texas A&M Univ.`;
expr:=Get(TFPreview::anything, corrections=true, update=true);
Set(MMLPreview(value) = MathML[Export](expr));
Set(CurrentTFname = expr);
end proc:EnableStep1:=proc()
Set(InputStep1(enabled)=true,InputStep1(background)=ColorInput):
Set(PreviewS1(enabled)=true,PreviewS1(background)=ColorPrevButton):
Set(CheckS1(enabled)=true,CheckS1(background)=ColorCheckButton):
Set(ShowS1(enabled)=true,ShowS1(background)=ColorShowButton):
Set(ReplyS1(enabled)=true):
Set(UseF1(enabled)=true):
Set(UseF2(enabled)=true):
Set(UseF3(enabled)=true):
Set(UseF4(enabled)=true):
Set(UseF5(enabled)=true):
Set(UseF6(enabled)=true):
end proc:ShowStep1:=proc()
global AnswerStep1,ProblemStep2:
AnswerStep1:=convert(luckyone,FormalPowerSeries,x):
Set (InputStep1=AnswerStep1):
ProblemStep2:=Int(AnswerStep1,x):
Set (MMLVStep2(value)=MathML[Export](ProblemStep2)):
Set (reply="Step 1 shown",reply(background)=ColorShow,reply(foreground)=ColorShowFrgd);
Set (ReplyS1=TEXTFeedbackShown,ReplyS1(background)=ColorShow,ReplyS1(foreground)=ColorShowFrgd,ReplyS1(enabled)=true);
EnableStep2():
end proc:EnableStep2:=proc()
Set (InputStep2(enabled)=true,InputStep2(background)=ColorInput):
Set (PreviewS2(enabled)=true,PreviewS2(background)=ColorPrevButton):
Set (ShowS2(enabled)=true,ShowS2(background)=ColorShowButton):
Set (CheckS2(enabled)=true,CheckS2(background)=ColorCheckButton):
end proc:ShowStep2:=proc()
global ser,TermSer,IntTermSer,IntegratedTerm,ProblemStep3,ValueOfMMLVHint3,CorrectAnswerStep3:
ser:=convert(luckyone,FormalPowerSeries,x):
TermSer:=op(1,ser):
IntegratedTerm:=int(TermSer,x):
IntTermSer:=Sum(IntegratedTerm,op(2,ser))+C:
Set(InputStep2=IntTermSer):
ProblemStep3:=Eval(Sum(IntegratedTerm,k=0..2),x=b)-Eval(Sum(IntegratedTerm,k=0..2),x=0):
Set(ReplyS2(background)=ColorShow,ReplyS2(foreground)=ColorShowFrgd,ReplyS2=TEXTFeedbackShown,ReplyS2(enabled)=true):
Set(reply(background)=ColorShow,reply="Step 2 shown",reply(foreground)=ColorShowFrgd):
if IndefSetting=false then
EnableStep3():
Set(MMLVStep3(value)=MathML[Export](ProblemStep3)):
ValueOfMMLVHint3:=Eval(sum(IntegratedTerm,k=0..2),x=b)-Eval(sum(IntegratedTerm,k=0..2),x=0):
Set(MMLVHint3(value)=MathML[Export](ValueOfMMLVHint3)):
CorrectAnswerStep3:=eval(sum(IntegratedTerm,k=0..2),x=b)-eval(sum(IntegratedTerm,k=0..2),x=0):
#Set(AnsStep3=CorrectAnswerStep3):
end if:
end proc:EnableStep3:=proc()
Set(InputStep3(enabled)=true,InputStep3(background)=ColorInput):
Set(HintS3(enabled)=true,HintS3(background)=ColorHintButton):
Set(CheckS3(enabled)=true,CheckS3(background)=ColorCheckButton):
Set(ShowS3(enabled)=true,ShowS3(background)=ColorShowButton):
Set(NoteS3(enabled)=true,NoteS3(background)=ColorWarning):
end proc:ShowStep3:=proc()
Set(InputStep3=evalf(CorrectAnswerStep3,3));
Set(ReplyS3=TEXTFeedbackShown,ReplyS3(enabled)=true,ReplyS3(background)=ColorShow,ReplyS3(foreground)=ColorShowFrgd):
Set(reply="Step 3 shown",reply(background)=ColorShow,reply(foreground)=ColorShowFrgd):
end proc:CheckStep1:=proc()
global userser,AnswerStep1,ProblemStep2:
AnswerStep1:=convert(luckyone,FormalPowerSeries,x):
userser:=Get(InputStep1::algebraic,corrections=true, update=true):
if simplify(normal(value(AnswerStep1) - value(userser)))=0
or combine(value(AnswerStep1) - value(userser), ln, symbolic)=0
or simplify(expand(value(AnswerStep1) - value(userser)))=0
or simplify(normal(value(AnswerStep1) - value(userser)))=0
or combine(value(AnswerStep1) - value(userser), ln, symbolic)=0
or simplify(expand(value(AnswerStep1) - value(userser)))=0
then Set (reply=TEXTReplyStep1Correct,reply(background)=ColorCorrect,reply(foreground)=ColorCorrectFrgd):
Set(ReplyS1="Correct!",ReplyS1(background)=ColorCorrect,ReplyS1(foreground)=ColorCorrectFrgd,ReplyS1(enabled)=true):
ProblemStep2:=Int(AnswerStep1,x):
Evalute(function=EnableStep2()):
Set (MMLVStep2(value)=MathML[Export](ProblemStep2)):
else Set (reply=TEXTReplyStep1Incorrect,reply(background)=ColorIncorrect,reply(foreground)=ColorIncorrectFrgd);
Set(ReplyS1="Incorrect",ReplyS1(background)=ColorIncorrect,ReplyS1(foreground)=ColorIncorrectFrgd):
end if:
end proc:CheckStep2:=proc()
global userInt,ser,TermSer,IntegratedTerm,IntTermSer,ProblemStep3,ValueOfMMLVHint3,CorrectAnswerStep3:
ser:=convert(luckyone,FormalPowerSeries,x):
TermSer:=op(1,ser):
IntegratedTerm:=int(TermSer,x):
IntTermSer:=Sum(IntegratedTerm,op(2,ser))+C:
userInt:=Get(InputStep2::algebraic,corrections=true, update=true):
if simplify(normal(value(IntTermSer) - value(userInt)))=C
or combine(value(IntTermSer) - value(userInt), ln, symbolic)=C
or simplify(expand(value(IntTermSer) - value(userInt)))=C
or simplify(normal(value(IntTermSer) - value(userInt)))=C
or combine(value(IntTermSer) - value(userInt), ln, symbolic)=C
or simplify(expand(value(IntTermSer) - value(userInt)))=C
then Set(reply(background)=ColorWarning,reply="you forgot to add C!!",reply(foreground)=ColorWarningFrgd,ReplyS2="Add C",ReplyS2(background)=ColorWarning,ReplyS2(foreground)=ColorWarningFrgd):
else
if simplify(normal(value(IntTermSer) - value(userInt)))=0
or combine(value(IntTermSer) - value(userInt), ln, symbolic)=0
or simplify(expand(value(IntTermSer) - value(userInt)))=0
or simplify(normal(value(IntTermSer) - value(userInt)))=0
or combine(value(IntTermSer) - value(userInt), ln, symbolic)=0
or simplify(expand(value(IntTermSer) - value(userInt)))=0
then Set (reply="Step 2 is correct.",reply(background)=ColorCorrect,reply(foreground)=ColorCorrectFrgd);
Set(ReplyS2(enabled)=true,ReplyS2="Correct!",ReplyS2(background)=ColorCorrect,ReplyS2(foreground)=ColorCorrectFrgd):
if IndefSetting=false then
EnableStep3():
Set(MMLVStep3(value)=MathML[Export](ProblemStep3)):
Set(MMLVHint3(value)=MathML[Export](ValueOfMMLVHint3)):
#Set(AnsStep3=CorrectAnswerStep3):
end if:
else Set (reply="step 2 is incorrect",reply(background)=ColorIncorrect,reply(foreground)=ColorIncorrectFrgd);
Set(ReplyS2="Incorrect",ReplyS2(background)=ColorIncorrect,ReplyS2(foreground)=ColorIncorrectFrgd):
end if:
end if:
ProblemStep3:=Eval(Sum(IntegratedTerm,k=0..2),x=b)-Eval(Sum(IntegratedTerm,k=0..2),x=0):
ValueOfMMLVHint3:=Eval(sum(IntegratedTerm,k=0..2),x=b)-Eval(sum(IntegratedTerm,k=0..2),x=0):
CorrectAnswerStep3:=eval(sum(IntegratedTerm,k=0..2),x=b)-eval(sum(IntegratedTerm,k=0..2),x=0):
end proc:CheckStep3:=proc()
global LowerBound,UpperBound;
local in3;
LowerBound:=evalf(CorrectAnswerStep3,3)-.0015; # I allow an error of +/- 1 digit in the thousandths place
UpperBound:=evalf(CorrectAnswerStep3,3)+.0015; # since this is an approximation, after all.
in3:=Get(InputStep3::realcons,corrections=true, update=true):
if in3>LowerBound and in3<UpperBound or in3=LowerBound or in3=UpperBound
then Set (reply="Step 3 is correct",reply(background)=ColorCorrect,reply(foreground)=ColorCorrectFrgd):
Set(ReplyS3="Correct!",ReplyS3(background)=ColorCorrect,ReplyS3(foreground)=ColorCorrectFrgd):
else Set (reply="Step 3 is incorrect",reply(background)=ColorIncorrect,reply(foreground)=ColorIncorrectFrgd):
Set(ReplyS3="Incorrect",ReplyS3(background)=ColorIncorrect,ReplyS3(foreground)=ColorIncorrectFrgd):
end if:
end proc:UseFormula:=proc(i)
Set(InputStep1=Formula[i]):
end proc:IntUsingSeries:= Maplet(onstartup = RunWindow(MAIN),
Window[MAIN](title="Using Maclaurin Series to Integrate",
[ background=colorbkgd,
[ background=colorbkgd,
BoxColumn(halign=none,valign=none,inset=0,spacing=10,background=colorbkgd,
VerticalGlue(),
Button("New Indefinite Integral",background=ColorNewButton,Evaluate(function="New_Problem(true)")),
Button("New Definite Integral",background=ColorNewButton,Evaluate(function="New_Problem(false)")),
VerticalGlue()
),
HorizontalGlue(),
BoxColumn(halign=none,valign=none,background=colorbkgd,border=true,
caption=CaptionGoal,
MathMLViewer[mainproblem](value=MathML[Export]("I"=Int(f(x),x=a..b)),width=200,height=60)
),
HorizontalGlue(),
Button("Quit",background=ColorCloseButton,Shutdown())
],
##STEP 1 - FIND A SERIES FOR THE INTEGRAND
[ halign=none, background=colorbkgd, border=true,
caption=CaptionStep1,
MathMLViewer[MMLf](value=MathML[Export](f(x)),width=150,height=60),
" = ",
TextField[InputStep1]("",width=40,enabled=false),
HorizontalGlue(),
Button("Formulas",Action(RunWindow(FORMULAS)),background=ColorFormulasButton),
Button[PreviewS1]("Preview", onclick=ASerPreview,background=colordisable,enabled=false),
Button[CheckS1]("Check", Evaluate(function=CheckStep1),background=colordisable,enabled=false),
TextField[ReplyS1]("",width=7,editable=false,enabled=false),
Button[ShowS1]("Show", Evaluate(function=ShowStep1),background=colordisable,enabled=false)
],
##STEP 2 - INTEGRATE THE SERIES WITH RESPECT TO X
[ halign=none, background=colorbkgd, border=true,
caption=CaptionStep2,
MathMLViewer[MMLVStep2](value=MathML[Export]("I" = Sum(Int(a[n]*x^n,x=a..b), n=0..infinity)),width=220,height=60),
"=",
TextField[InputStep2]("",width=50,enabled=false),
HorizontalGlue(),
Button[PreviewS2]("Preview", onclick=AIntPreview,background=colorbkgd,enabled=false),
Button[CheckS2]("Check", Evaluate(function=CheckStep2),background=colorbkgd,enabled=false),
TextField[ReplyS2]("",width=7,editable=false,enabled=false),
Button[ShowS2]("Show", Evaluate(function=ShowStep2),background=colorbkgd,enabled=false)
],
##STEP 3 - ONLY FOR DEFINITE INTEGRALS
BoxColumn(halign=none, valign=none, inset=0, spacing=0, background=colorbkgd, border=true,
caption=CaptionStep3,
Label[S3Disabled](TEXTS3Disabled,visible=false),
[ background=colorbkgd,
MathMLViewer[MMLVStep3](value=MathML[Export](""),width=500,height=80),
Label[S3equalsign](" = "),
TextField[InputStep3]("",width=7,enabled=false),
HorizontalGlue(),
Button[NoteS3]("Note",RunWindow(NOTES3),enabled=true,background=colorbkgd,visible=true,enabled=false),
Button[HintS3]("Hint",RunWindow(HINTSTEP3),enabled=false,background=colorbkgd,visible=true),
Button[CheckS3]("Check", Evaluate(function=CheckStep3),enabled=false,background=colorbkgd),
TextField[ReplyS3]("",width=7,editable=false,enabled=false),
Button[ShowS3]("Show", Evaluate(function=ShowStep3),enabled=false,background=colorbkgd)
]
),
[ background=colorbkgd,
TextBox[reply]("",width=60,height=1,editable=false,background=white)
],
[ halign=none, background=ColorFooter,
Label("Programmer: David Migl", font=FontFooter),
HorizontalGlue(),
Label("Copyright: P. Yasskin 2008", font=FontFooter)
]
]),
Window[PREVIEW]( title=TEXTtitlePREVIEW, defaultbutton=UpdatePreview,
[ background=colorbkgd,halign=none,
[
TextField[TFPreview](width=50,background=ColorPrevButton),
Button[UpdatePreview](TEXTBUpdate, Evaluate(function = Update_Preview),background=ColorPrevButton),
Button[ClosePreview](TEXTBClose, CloseWindow(PREVIEW),background=ColorCloseButton)
],
[
MathMLViewer[MMLPreview](value=MathML[Export](""), width=500, height=100)
]
]),
Window[FORMULAS](title="Formulas",
[ background=colorbkgd, halign=none,
[ background=colorbkgd,
HorizontalGlue(),
"Function",
HorizontalGlue(),
HorizontalGlue(),
HorizontalGlue(),
"Maclaurin Series",
HorizontalGlue(),
HorizontalGlue(),
HorizontalGlue(),
Button[CloseFormulas](TEXTBClose, CloseWindow(FORMULAS),background=ColorCloseButton)
],
[ background=colorbkgd,
MathMLViewer(value=MathML[Export](1/(1-t)),width=100,height=60),
"=",
MathMLViewer(value=MathML[Export](Formula[1]),width=200,height=60),
Button[UseF1](TEXTBFormulaUse, onclick=AUse1,enabled=false)
],
[ background=colorbkgd,
MathMLViewer(value=MathML[Export](e^t),width=100,height=60),
"=",
MathMLViewer(value=MathML[Export](Formula[3]),width=200,height=60),
Button[UseF3](TEXTBFormulaUse, onclick=AUse3,enabled=false)
],
[ background=colorbkgd,
MathMLViewer(value=MathML[Export](sin(t)),width=100,height=60),
"=",
MathMLViewer(value=MathML[Export](Formula[4]),width=200,height=60),
Button[UseF4](TEXTBFormulaUse, onclick=AUse4,enabled=false)
],
[ background=colorbkgd,
MathMLViewer(value=MathML[Export](cos(t)),width=100,height=60),
"=",
MathMLViewer(value=MathML[Export](Formula[5]),width=200,height=60),
Button[UseF5](TEXTBFormulaUse, onclick=AUse5,enabled=false)
],
[ background=colorbkgd,
MathMLViewer(value=MathML[Export](ln(1+t)),width=100,height=60),
"=",
MathMLViewer(value=MathML[Export](Formula[2]),width=200,height=60),
Button[UseF2](TEXTBFormulaUse, onclick=AUse2,enabled=false)
],
[ background=colorbkgd,
MathMLViewer(value=MathML[Export](arctan(t)),width=100,height=60),
"=",
MathMLViewer(value=MathML[Export](Formula[6]),width=200,height=60),
Button[UseF6](TEXTBFormulaUse, onclick=AUse6,enabled=false)
]
]
),
Window[HINTSTEP3](width=700,height=300,title="Step 3 Hint",
[ background=colorbkgd,
TextBox(value=TEXTHintStep3,height=3),
MathMLViewer[MMLVHint3](value=MathML[Export](""),width=600,height=100)
]
),
Window[NOTES3](width=500,height=200,title="Note",
[ background=colorbkgd,
TextBox(TEXTS3Note,height=250)
]
),
Action[ARunPreview](RunWindow(PREVIEW)),
Action[ASerPreview](Evaluate(function = "Preview(InputStep1)")),
Action[AIntPreview](Evaluate(function="Preview(InputStep2)")),
Action[AUse1](Evaluate(function="UseFormula(1)"),CloseWindow(FORMULAS)),
Action[AUse2](Evaluate(function="UseFormula(2)"),CloseWindow(FORMULAS)),
Action[AUse3](Evaluate(function="UseFormula(3)"),CloseWindow(FORMULAS)),
Action[AUse4](Evaluate(function="UseFormula(4)"),CloseWindow(FORMULAS)),
Action[AUse5](Evaluate(function="UseFormula(5)"),CloseWindow(FORMULAS)),
Action[AUse6](Evaluate(function="UseFormula(6)"),CloseWindow(FORMULAS))
):Maplets[Display]( IntUsingSeries );