Animated Tangent Planes
by Brandon Cook
under the supervision of P. Yasskin, 2008
restart:with(plots):with(plottools):
AniTanPlane:=proc(function, xrange, yrange, resolution::posint:=24)
local xvar, xrng, yvar, yrng, xleft, xright, yleft, yright, xlength, ylength,
radius, crv, fx, fy, A, B, fTan, n, GraphTan, Graphf, xTrace, yTrace, ptot, t, i;
options `Copyright P. Yasskin, 2008`;
xvar:=lhs(xrange):
xrng:=rhs(xrange):
xleft:=lhs(xrng):
xright:=rhs(xrng):
yvar:=lhs(yrange):
yrng:=rhs(yrange):
yleft:=lhs(yrng):
yright:=rhs(yrng):
xlength:=xright-xleft;
ylength:=yright-yleft;
radius:=.4*min(xlength,ylength);
crv:=[radius*cos(t), radius*sin(t)]; #crv establishes the path of the tangent plane
fx:= diff(function, xvar); #below creates the tangent plane
A:=eval(fx, Equate([xvar,yvar], crv));
fy:= diff(function, yvar);
B:= eval(fy, Equate([xvar,yvar], crv));
fTan:=A*(xvar-crv[1])+B*(yvar-crv[2])+eval(function, Equate([xvar,yvar],crv));
n:= resolution; #number of frames
for i from 0 to n-1 do
t:=i*2*Pi/n;
GraphTan:=plot3d(fTan, xrange, yrange, thickness=1, transparency=.44, color=red):
Graphf:=plot3d(function, xrange, yrange, thickness=1, transparency=.8, color=blue):
xTrace:=spacecurve([xvar, crv[2], eval(function, yvar=crv[2])], xrange, thickness=3, color=red):
yTrace:=spacecurve([crv[1], yvar, eval(function, xvar=crv[1])], yrange, thickness=3, color=red):
ptot[i]:=display3d(GraphTan, Graphf, xTrace, yTrace):
end do:
display([seq(ptot[i], i=0..(n-1))], insequence=true);
end proc:
AniTanPlane(x*y, x=-5..5, y=-6..6, 48);