Approximating Integrals using Maclaurin Series
Bryan Layton & Tyler Savell
TA: Jill Cockerham
Professor: Dr. Philip Yasskin
253 Honors Spring 2009
restart:
with(Maplets[Tools]): with(Maplets[Elements]):
StartEngine():
lightcyan:="#DDFFFF":
showorange:="#FFBB55":
ender:="#FFDD55":
ColorFooter:=lightcyan:
FontFooter:=Font("helvetica",10):
randomize():
showtext:=[
"Try it yourself next time!",
"Try it yourself next time!...LOSER!!!",
"Really...? You have to use the helpbox...?",
"My mother could do this question!",
"You couldn't do it, go cry in a corner."]:
rtext:=rand(1..nops(showtext)):
cortext:=[
"You got it right, bud!",
"Perfect Job...keep it up.",
"Bullseye!",
"Correct! Try another question.",
"Right, now do another."]:
ctext:=rand(1..nops(cortext)):
wrtext:=[
"Sorry bud, wrong answer...",
"Completely wrong, now try it again.",
"It's wrong, but don't give up. You can do it.",
"Incorrect. Try again.",
"Wrong, but please don't give up! Have some faith in yourself."]:
wtext:=rand(1..nops(wrtext)):
funcs:=[1/(1-u), exp(u), sin(u), cos(u), arctan(u)]:
rfuncs:=rand(1..nops(funcs)):
randdega:=rand(2..3):
randdegb:=rand(3..6):
randa:=rand(1..10):
randp:=rand(2..5):
randb1:=rand(-5..5):
randdb:=rand(1..5):
ask:=proc()
global fupoly, fxpoly, approxdef, approxindef, integ, Integ, exactdef, degu, degx, n,
whichp, whicha, func, b1, b2, whichfunc, u1, dec:
whichfunc:=rfuncs():
func:=funcs[whichfunc]:
whicha:=randa():
whichp:=randp():
b1:=randb1()/10.:
b2:=b1+randdb()/10.:
if whichfunc = 1 then
n := (1./whicha)^(1/whichp):
while (n >= b1) and (n <= b2) do
dec := b2 - floor(n * 10)/10:
b1 := b1 - dec:
b2 := b2 - dec:
end do:
n:= n * (-1):
while (n >= b1) and (n <= b2) do
dec := b2 - floor(n * 10)/10:
b1 := b1 - dec:
b2 := b2 - dec:
end do:
end if:
u1:=whicha*x^whichp:
integ:=eval(func,u=u1);
Integ:=Int(integ, x=evalf(b1,2)..evalf(b2,2)):
if whichfunc in {1,2} then
degu:=randdega()
else
degu:=randdegb()
end if:
degx:=whichp*degu:
fupoly:=convert(taylor(func,u=0,degu+1),polynom):
fxpoly:=eval(fupoly,u=u1);
approxindef:=int(fxpoly,x);
approxdef:=int(fxpoly,x=b1..b2);
exactdef:=int(integ,x=b1..b2);
Set(question(value)=MathML[Export](Integ)):
Set(graph1=plot(integ, x=b1..b2)):
Set(Lfu(caption)=sprintf("Degree %a Maclaurin Polynomial for %a = ", degu, func)):
Set(Lfx(caption)=sprintf("Degree %a Maclaurin Polynomial for %a =", degx, integ)):
Set(answer1=""):
Set(answer2=""):
Set(answer3=""):
Set(answer4=""):
Set(answer5=""):
Set(reply="", reply(background)=white):
end proc:
checkfupoly:=proc()
global fupoly, wrtext, cortext, ctext, wtext:
local userfupoly, whichtextc, whichtextr:
userfupoly:=Get(answer1::polynom, corrections=true, update=true):
whichtextc:= ctext():
whichtextr:= wtext():
if userfupoly = fupoly
then Set(reply=cortext[whichtextc], reply(background)=green)
else Set(reply=wrtext[whichtextr], reply(background)=red)
end if:
end proc:
checkfxpoly:=proc()
global fxpoly, wrtext, cortext, ctext, wtext:
local userfxpoly, whichtextc, whichtextr:
userfxpoly:=Get(answer2::polynom, corrections=true, update=true):
whichtextc:= ctext():
whichtextr:= wtext():
if userfxpoly = fxpoly
then Set(reply=cortext[whichtextc], reply(background)=green)
else Set(reply=wrtext[whichtextr], reply(background)=red)
end if:
end proc:
checkindef:=proc()
global approxindef, wrtext, cortext, ctext, wtext:
local userindef, whichtextc, whichtextr:
userindef:=Get(answer3::polynom, corrections=true, update=true):
whichtextc:= ctext():
whichtextr:= wtext():
if userindef = approxindef
then Set(reply=cortext[whichtextc], reply(background)=green)
else Set(reply=wrtext[whichtextr], reply(background)=red)
end if:
end proc:
checkdef:=proc()
global approxdef, wrtext, cortext, ctext, wtext:
local userdef, whichtextc, whichtextr:
userdef:=Get(answer4::realcons, corrections=true, update=true):
whichtextc:= ctext():
whichtextr:= wtext():
if abs(userdef - approxdef) < 5*10^(-3) * abs(approxdef)
then Set(reply=cortext[whichtextc], reply(background)=green)
else Set(reply=wrtext[whichtextr], reply(background)=red)
end if:
end proc:
showfupoly:=proc()
global fupoly, showtext, rtext:
local whichtext:
whichtext:= rtext():
Set(answer1=fupoly):
Set(reply=showtext[whichtext], reply(background)=showorange):
end proc:
showfxpoly:=proc()
global fxpoly, showtext, rtext:
local whichtext:
whichtext:= rtext():
Set(answer2=fxpoly):
Set(reply=showtext[whichtext], reply(background)=showorange):
end proc:
showindef:=proc()
global approxindef, showtext, rtext:
local whichtext:
whichtext:= rtext():
Set(answer3=approxindef):
Set(reply=showtext[whichtext], reply(background)=showorange):
end proc:
showdef:=proc()
global approxdef, showtext, rtext:
local whichtext:
whichtext:= rtext():
Set(answer4=evalf(approxdef,4)):
Set(reply=showtext[whichtext], reply(background)=showorange):
end proc:
showexact:=proc()
global exactdef:
Set(answer5=exactdef):
Set(reply="How well does it agree?"):
end proc:
MaclSerInteg:=Maplet(onstartup = RunWindow(MAIN),
Window[MAIN](title="Approximating Integrals using Maclaurin Series",
[ [ Button("New Integral", Evaluate(function = "ask"), background=magenta),
" ",
Button("Exit", Shutdown(), background=pink)
],
[ [ border=true,
caption="Approximate the integral:",
MathMLViewer[question](value=MathML[Export](Int(f(x), x=0..1)),
width=300, height=100)
],
[ border=true,
caption="Plot of the integrand:",
Plotter[graph1](height=250, width=250)
]
],
BoxColumn( border=true,
caption="Enter the Maclaurin Polynomials:",
[ halign=none,
Label[Lfu]("Degree d Maclaurin Polynomial for f(u) = "),
HorizontalGlue(),
TextField[answer1](width=30, background=cyan),
Button("Check", Evaluate(function = "checkfupoly"), background=green),
Button("Show", Evaluate(function = "showfupoly"), background=showorange)
],
[ halign=none,
Label[Lfx]("Degree d Maclaurin Polynomial for f(u(x)) = "),
HorizontalGlue(),
TextField[answer2](width=30, background=cyan),
Button("Check", Evaluate(function = "checkfxpoly"), background=green),
Button("Show", Evaluate(function = "showfxpoly"), background=showorange)
]
),
BoxColumn( border=true,
caption="Approximate the Integral:",
[ halign=none,
"Indefinite Integral =",
TextField[answer3]("", width=30, background=cyan),
HorizontalGlue(),
Button("Check", Evaluate(function = "checkindef"), background=green),
Button("Show", Evaluate(function = "showindef"), background=showorange)
],
[ halign=none,
"Definite Integral = ",
TextField[answer4](width=10, background=ender),
"Give answer to within 0.1%.",
HorizontalGlue(),
Button("Check", Evaluate(function = "checkdef"), background=green),
Button("Show", Evaluate(function = "showdef"), background=showorange)
],
[ halign=none,
"Exact Definite Integral = ",
TextField[answer5](width=10, background=white),
HorizontalGlue(),
Button("Show", Evaluate(function = "showexact"), background=showorange)
]
),
[ TextField[reply](width=40, editable=false, background=white)
],
[ halign=none, background=ColorFooter,
Label("Programmers: Bryan Layton & Tyler Savell", font=FontFooter),
HorizontalGlue(),
Label("Copyright: P. Yasskin 2009", font=FontFooter)
]
]
)
):
Maplets[Display]( MaclSerInteg ):